Minecraft超级工厂脚本分享

y帮助

传输面

• 上: top side

• 下: bottom side

• 东: east side

• 南: south side

• 西: west side

• 北: north side

资源类型

物品

item

流体

fluid

化学品

chemical

gas

能量

forge_energy

fe

rf

从A到B传输物品

name "物品传输"
every 1 seconds do
    input item:: from "A" top side
    output item:: to "B" bottom side
end

Powah反应堆自动化

name "Powah反应堆"
every 8 seconds do
    input item:: from "ME接口"
-- 如果用水
    input fluid:: from "ME接口"
    output item:: to "反应堆"
    output fluid:: to "反应堆"
end

every 5 ticks do
    input rf:: from each "反应堆"
    output rf:: to "通量访问点"
end

水培床

name "水培床"
every 2 ticks do
    input rf:: from "ME Flux Interface" each side
    output rf:: to each "水培床" each side
end

every 40 ticks do
    input fluid:: from "ME Large Interface"
    output fluid:: to each "水培床"
    input item:: from each "水培床" bottom side
    output item:: to "ME Large Interface"
end

模拟室&&战利品制造机

name "模拟室/战利品制造机"
every 2 ticks do
    input rf:: from "ME Flux Interface"
    output rf:: to each "能量输入"
end

every 4 seconds do
    input hostilenetworks:prediction_matrix from "ME Interface"
    output hostilenetworks:prediction_matrix to each "模拟室"
    forget
    input item:: from each "模拟室", "战利品制造机"
    output item:: to "ME Interface"
end

盆栽自动放究极耕地和种子, 以及一键清空盆栽种植栏位

注: 请使用拉杆开启

-- 从盆栽回收一切
--every redstone pulse do
--    input item:: from each "盆栽" slots 0-1
--    output item:: to "箱子I"
--end

-- 自动放究极耕地和种子
every redstone pulse do
    input mysticalagradditions:insanium_farmland from "箱子I"
    output 1 mysticalagradditions:insanium_farmland to each "盆栽" slots 0
    forget
    input item:: except mysticalagradditions:insanium_farmland from "箱子I"
    output 1 item:: to each "盆栽" slots 1
end

龙之进化注入装置

name "龙之进化注入装置"

-- Core => 聚合核心
-- Storage => 箱子
-- Power => 通量访问点
-- Worker => 注入器
-- Interface => 接口|供应器

every tick do
    input rf:: from Power
    output rf:: to each Worker each side
end


every 1 seconds do
    if Core has =0 then
        if Storage slot 0 has =5 *large_chaos_frag* then
            output retain 1 *large_chaos_frag* to Core top side
            output retain 1 to each Worker top side
        end
            input from Storage slots 0
            output to Core top side
            forget
            input from Storage slots 1-19
            output retain 1 to each Worker top side
    end
    input from Core bottom side
    output to Interface
end